2x windows 98 auf einer Platte! Wie???

[Anárion]

Hallo,

ich möchte auf einer leeren Platte 2mal Windows 98 installieren. Einmal die deutsche Version.....dann die persische.......ich habe Partition Magic7 gekauft....wie gehe ich vor?? Ich habe keine Ahnung! Ich möchte am Start auswählenb können welches Version ich starte.

Danke

Firouz

[Anárion]

das ist nicht mein Account,der ist von meinem Freund (Rebel304)

[Razor]

Mindestens 2 Partitonen einrichten (besser sind so 4-5, je nach Plattengröße und geplantem Einsatz).

Du gehst dann folgendermaßen vor:

1) Installation des ersten Win98 auf einer Partition
2) Umbenenen der folgenden Dateien:
- IO.SYS -> IO.W9A
- MSDOS.SYS -> MSDOS.W9A
- SYSTEM.1ST -> SYSTEM.W9A
- COMMAND.COM -> COMMAND.W9A
- CONFIG.SYS -> CONFIG.W9A
- AUTOEXE.BAT -> AUTOEXEC.W9A
3) temporäres Umbenennen der Datei WIN.COM im <Windows>-Verzeichnis nach WIN.CO1 oder ähnlichem, da sonst das SETUP der 2. Installation abbricht.
4) Installation des zweiten Win98 auf einer anderen Partition
5) Erstellen eines Batches, der die beiden Versionnen umschalten kann (folgt dieser Anleitung)
6) Die temprär umbenannte WIN.CO1 der ersten Installation nach WIN.COM umbenennen.
FERTIG !

Der Batch sollte dann wie folgt aussehen:
@echo off
c:
cd \
if exist c:\autoexec.w9a goto winw9bwinw9a
if exist c:\autoexec.w9b goto winw9awinw9b
goto error1
:winw9bwinw9a
echo.
echo Es wird von Windows w9b auf Windows w9a umgeschaltet ...
echo.
if not /%1/==/auto/ pause
if not /%1/==/auto/ echo.
echo **** Orginal-Dateien entsichern
attrib io.sys -r -h -s
attrib system.1st -r -h -s
attrib msdos.sys -r -h -s
echo **** Winw9a-Dateien entsichern
attrib io.w9a -r -h -s
attrib system.w9a -r -h -s
attrib msdos.w9a -r -h -s
echo **** Orginal-Dateien zu Winw9b-Dateien wandeln
ren command.com command.w9b
ren config.sys config.w9b
ren autoexec.bat autoexec.w9b
ren io.sys io.w9b
ren system.1st system.w9b
ren msdos.sys msdos.w9b
echo **** Winw9a-Dateien zu Orginal-Dateien wandeln
ren command.w9a command.com
ren config.w9a config.sys
ren autoexec.w9a autoexec.bat
ren io.w9a io.sys
ren system.w9a system.1st
ren msdos.w9a msdos.sys
echo **** Winw9b-Dateien sichern
attrib io.w9b +r +h +s
attrib system.w9b +r +h +s
attrib msdos.w9b +r +h +s
echo **** Orginal-Dateien sichern
attrib io.sys +r +h +s
attrib system.1st +r +h +s
attrib msdos.sys +r +h +s
echo.
goto ende
:winw9awinw9b
echo.
echo Es wird von Windows w9a auf Windows w9b umgeschaltet ...
echo.
if not /%1/==/auto/ pause
if not /%1/==/auto/ echo.
echo **** Orginal-Dateien entsichern
attrib io.sys -r -h -s
attrib system.1st -r -h -s
attrib msdos.sys -r -h -s
echo **** Winw9b-Dateien entsichern
attrib io.w9b -r -h -s
attrib system.w9b -r -h -s
attrib msdos.w9b -r -h -s
echo **** Orginal-Dateien zu Winw9a-Dateien wandeln
ren command.com command.w9a
ren config.sys config.w9a
ren autoexec.bat autoexec.w9a
ren io.sys io.w9a
ren system.1st system.w9a
ren msdos.sys msdos.w9a
echo **** Winw9b-Dateien zu Orginal-Dateien wandeln
ren command.w9b command.com
ren config.w9b config.sys
ren autoexec.w9b autoexec.bat
ren io.w9b io.sys
ren system.w9b system.1st
ren msdos.w9b msdos.sys
echo **** Winw9a-Dateien sichern
attrib io.w9a +r +h +s
attrib system.w9a +r +h +s
attrib msdos.w9a +r +h +s
echo **** Orginal-Dateien sichern
attrib io.sys +r +h +s
attrib system.1st +r +h +s
attrib msdos.sys +r +h +s
echo.
goto ende
:ende
echo.
echo Umstellung durchgefuehrt ...
echo.
goto exit
:error
echo.
echo Sie befinden sich nicht in der Dos 6.21 Umgebung,
echo oder eine vorherige Umschaltung lief nicht planungsgemaess ...
echo.
echo (Der Batch wird abgebrochen !)
echo.
pause
goto exit
:error1
echo.
echo Switching kann nicht durchgef?hrt werden, da nicht implementiert !!!
echo.
echo (Der Batch wird abgebrochen !)
echo.
pause
goto exit
:exit
if /%1/==/auto/ echo.
if /%1/==/auto/ echo ******* Das System wird jetzt neu gestartet *******
if /%1/==/auto/ echo.
if /%1/==/auto/ reboot
:exitFIN
echo on

Wenn nun dieser Batch aufgerufen wird, dann wechselt dieser dann von einer Version zur anderen.

Der Parameter 'auto' kann angegeben werden, um die Pausen zwischen den einzelnen Schritten zu deaktivieren. Der Reboot am Ende des Batches funktioniert nur, wenn man das kleine Tool 'Reboot.EXE' besitzt. Ansonsten muß man halt den Rechner selber neu starte...

Much fun with it !

Razor

P.S.: Diesen Batch habe ich in abgewandelter Form dazu benutzt, um zwischen Win95c und Win98SE unter dem NT-Bootmanager zumzuschalten... aber da ich Win95c nicht mehr benutze, hat's sich damit erledigt...
;-)

[Thowe]

So mache ich es:

Windows ganz normal installieren
z.B. C:\WIN98
Nach der Installation den Ordner umbenennen
ren C:\WIN98 C:\WIN1

Zweites Windows installieren und hier wieder als Ordner
C:\WIN98
angeben

Danach die CONFIG.SYS und AUTOEXEC.BAT editieren, bei mir sieht das so aus

Config


[menu]
menuitem=win1,Windows TEST-Version zum vollm?llen
menuitem=win2,Windows echte Version - Sauber bleiben
menuitem=win3,Sparversion zum testen
menudefault=win2,10
[common]
device=c:\service\devices\kbd.sys
rem device=c:\service\devices\cdrom.sys /d:cd1
[win1]
[win2]
[win3]


Autoexec

@echo off
smartdrv
set temp=e:\temp
set tmp=e:\temp
ren win98 win1
ren win98 win2
ren win98 win3
if "%config%"=="win1" goto win1
if "%config%"=="win2" goto win2
if "%config%"=="win3" goto win3
goto ende
:win1
ren win1 win98
goto ende
:win2
ren win2 win98
goto ende
:win3
ren win3 win98
goto ende
:ende


Die Autoexec könnte man sogar noch kürzen, habe ich aber absichtlich nicht damit man einzelne Treiber noch zusätzlich einbinden kann.

das kbd.sys wirst du nicht haben, also in die Autoexec unterhalb von smartdrv das berüchtigte keyb gr einfügen.

Die TEMP Variable ggf. einfach löschen oder aber anpassen.

[Razor]

Tja, Thowe...

Das sind dann aber keine unabhängigen Betriebssysteme mehr. Vor allem das Programme-Verzeichnis (Windows-Update, Internet-Explorer, Media-Player etc.pp) enthält dann nur eine Sprache und möglicherweise differente Versionen..

'Sauberer' ist es doch, die beiden Win98'iger auf verschiedenen Partitionen zu halten, oder ?
;-)

Razor

[Thowe]

In der Reg die Pfade für jede Winversion ändern, wäre ne Möglichkeit. z.B. nach

Programme1
Programme2

usw. ist ja kein Prob.

aber wie gehabt viele Wege führen nach Paris (oder so).

[Anárion]

Danke Junx,

Firouz ist überglücklich! :) (Ich weniger wegen Accountmißbrauch :D)